{
  stdenv,
  lib,
  fetchFromGitHub,
  pkg-config,
  makeWrapper,
  ptlib,
  opal,
}:

let
  version = "4.6.2";
in
stdenv.mkDerivation {
  pname = "t38modem";
  inherit version;

  src = fetchFromGitHub {
    owner = "hehol";
    repo = "t38modem";
    rev = version;
    hash = "sha256-QzAuEndRA3Vyucq5WAKLhvfoIOyqpWfnXseHvYdCUQU=";
  };

  nativeBuildInputs = [
    pkg-config
    makeWrapper
  ];
  buildInputs = [
    ptlib
    opal
  ];

  strictDeps = true;

  buildPhase = ''
    PTLIBPLUGINDIR="${ptlib}/lib/ptlib-${ptlib.version}:${opal}/lib/opal-${opal.version}"
    NIX_CFLAGS_COMPILE="-Wno-narrowing $NIX_CFLAGS_COMPILE"
    make
  '';

  installPhase = ''
    mkdir -p $out/bin
    install -m755 ./t38modem $out/bin/t38modem

    wrapProgram $out/bin/t38modem \
      --set LD_LIBRARY_PATH "${ptlib}/lib:${opal}/lib" \
      --set PTLIBPLUGINDIR "${ptlib}/lib/ptlib-${ptlib.version}:${opal}/lib/opal-${opal.version}"
  '';

  meta = {
    description = "t38modem";
    homepage = "https://github.com/hehol/t38modem";
    platforms = with lib.platforms; unix;
    license = lib.licenses.mpl10;
    downloadPage = "https://github.com/hehol/t38modem/releases/tag/${version}";
  };
}